gnuplot 5.0お祝いの画像

gnuplot 5.0リリースを祝して作成し、ページに掲載した画像です。色に透明度を設定できるようになったり（rgbalpha）、Enhanced Textが強化されたりといった、5.0の新機能もふんだんに使った図になっています。なお、この例ではユニコードのUTF-8エンコードを使う設定になっているので、ご使用のエディタで文字コードをUTF-8N（なければUTF-8）に設定した上でスクリプトを保存し実行して下さい。

set term wxt background rgb "#FFDDDD"
set angles degrees

# エンコードの設定
set encoding "utf8"

# 枠などを消す
set lmargin 0
set tmargin 0
set rmargin 0
set bmargin 0
set format xy ""
unset xtics
unset ytics
set border 0
# 枠などを消す ここまで

set xrange [0:1]
set yrange [0:1]


N = 10
dr = 0.02
# 文字の周りにたくさんラベルを打って、ぼんやりした輪郭を作る。
do for [i=1:N] {
     set label 100+i at graph 0.5 + dr*cos(360.0/N*i),0.8+dr*sin(360.0/N*i) \
     center "{/Meiryo:Bold=80 祝}" front tc rgb "#aaFFFFFF"
     }
set label 100+N+1 at graph 0.5,0.8 center "{/Meiryo:Bold=80 祝}" front tc rgb "blue"

dr = 0.015
# 文字の周りにたくさんラベルを打って、ぼんやりした輪郭を作る。
do for [i=1:N] {
     set label 200+i at graph 0.5 + dr*cos(360.0/N*i),0.35+dr*sin(360.0/N*i) \
     center "{/Arial:Bold=40 gnuplot 5.0 release}" front tc rgb "#aaFFFFFF"
     }
set label 200+N+1 at graph 0.5,0.35 center "{/Arial:Bold=40 gnuplot 5.0 release}" front tc rgb "red"


unset colorbox
dummy = rand(time(0)) # 乱数の種生成
set samples 700
plot "+" using (rand(0)):(rand(0)):(rand(0)*4):(hsv2rgb(rand(0),0.6,1)+256**3*int(256*rand(0))) \
     with p pt 13 ps variable lc rgb variable notitle